Oje noch ein Blog » VBS

VBS: Email versenden mit Outlook

Daniel — Thu, 22 Sep 2011 07:40:24 +0000

Als Parameter kann Empfänger sowie die Antwortadresse angegeben werden. Die eMail Adresse wird auf Format geprüft.

' ################################ ' ' SendMail.vbs ' ' Sends an eMail through Microsoft Outlook ' ' Usage: SendMail.vbs recipient@domain.com reply-to-address@domain.com ' 09/22/2011 Daniel Ristic ' ' ################################


If WScript.Arguments.Count < 2 then

	WScript.Echo "Usage: SendMail.vbs recipient@domain.com reply-to-address@domain.com"

Else

	Set RegEx = New regexp

	RegEx.Pattern = "^([a-zA-Z0-9_\-\.]+)@((\[[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.)|(([a-zA-Z0-9\-]+\.)+))([a-zA-Z]{2,4}|[0-9]{1,3})(\]?)$"

	RegEx.IgnoreCase = true

	If RegEx.Test(WScript.Arguments.Item(0)) <> true OR RegEx.Test(WScript.Arguments.Item(1)) <> true Then

		WScript.Echo "Error: Invalid email addresses. Please check format."

	Else

		Call SendOutlookEmail(WScript.Arguments.Item(0),WScript.Arguments.Item(1))

	End If

End If
Function SendOutlookEmail(strTo, strReplyTo)
	' Create a new Outlook Object

	Set OutlookApp = CreateObject("Outlook.Application")

	Set OutlookMail = OutlookApp.CreateItem(0)

	' ################################
	' Get Timezone Name

	Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")

	Set colItems = objWMIService.ExecQuery("Select * from Win32_TimeZone")
	For Each objItem in colItems

		Timezone = objItem.Caption

	Next
	' Send Email

	With OutlookMail

		.BodyFormat = 1

		.To = strTo

		.Subject = Date() & ";" & Time() & ";" & Timezone

		.Body = Date() & vbCrLf &  Time() & vbCrLf  &  Timezone

		.replyRecipients.Add(strReplyTo)

		.Send

	End With

End Function

VBS Einzeiler zum ermitteln von 64 oder 32 Bit Windows Betriebssystem

Daniel — Mon, 12 Sep 2011 11:36:38 +0000

Der Fuktionsaufruf gibt 64 oder 32 zurück.

GetObject("winmgmts:root\cimv2:Win32_Processor='cpu0'").AddressWidth

Standortabhängiges Anmeldescript

Daniel — Mon, 28 Sep 2009 07:50:59 +0000

Den aktuellen Standort eines Benutzers zu ermitteln, definiert durch die Active Directory Sites, funktioniert folgender VBS Code:

On Error Resume Next
Set wshShell = WScript.CreateObject( "WScript.Shell" )
strUserDomain = wshShell.ExpandEnvironmentStrings( "%USERDOMAIN%" )

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery("SELECT ClientSiteName FROM Win32_NTDomain WHERE DomainName = '"& strUserDomain &"'",,48)

For Each objItem in colItems
  ' Hier wird der erkannte Sitename der Anmeldedomäne ausgegeben.
  strSiteName = objItem.ClientSiteName
next

select case strSiteName
	case "Berlin"
             ' Tu irgendwas
	case "München"
             ' Tu irgendwas anderes
end select

Getestet unter Windows XP, Windows 2003, Vista und Windows 7.